AppleScriptでフォルダ階層以下すべての指定種類のファイルリストを取得〜指定kind救出作戦

2014年6月19日2016年6月8日AppleScript,Mac

AppleScriptで、あるフォルダ階層以下(下位フォルダも含む)に入っている、すべてのファイルのリスト(aliasのリスト)を取る必要がありました。

“System Events"でファイル一覧取得
kind of …で指定した種類のファイルを記録
“System Events"でフォルダ一覧取得
それぞれのフォルダに付いて、再起的に同じ事を繰り返す

次の例の場合、png形式の画像ファイルのリストを作っています。

(* Gather files whose are "kdTyp"
 * Copyright (c) 2014 webmaster@oichinote.com
 * Created on 2014-06-19
 * Licence is GPL2
 *)

global kdList
global kdType
set kdList to {}
set kdType to "PNG イメージ"

set startFolder to choose folder
gatherKind(startFolder)
display dialog length of kdList

-- Gather all files whose kind is kdType to kdList
on gatherKind(startFolder)
	-- get all files
	tell application "System Events"
		set allFiles to every file of startFolder
	end tell
	
	-- get files of kdType
	repeat with aFile in allFiles
		-- set name_of_file to (name of aFile)
		if kind of aFile is equal to kdType then
			set end of kdList to (aFile as alias)
		end if
	end repeat
	
	-- get all folders
	tell application "System Events"
		set newFolders to every folder of startFolder
	end tell
	
	-- recuresive call
	repeat with aFolder in newFolders
		gatherKind(aFolder)
	end repeat
end gatherKind

見つかったファイルを、alias形式でどんどん追加して行きます。aliasとは、多分CNIDの事だと思います。

最初、&演算子でリストの追加をしていたのですが、"end of …"を使った方が速いと、次のページに書かれていたので試してみました。